今天看啥
热点:

基于 Arduino 的温度+湿度传感器,arduino湿度传感器


虽然根本不懂电路,但经过查阅资料,总算是实现了。在这里做一个记录,以免忘记。

开发环境

硬件

  • Arduino uno r3 开发板,点我看Arduino各版本的比较,uno的第3个版本,也是目前市面上用于学习最多的板子,意大利原版的价格是20欧,淘宝山寨板的价格是20元左右。
  • 温度湿度传感器,型号DHT11,几块钱,淘宝上都有。
  • 杜邦线,1块钱10根(注意分公母,区别是插还是被插)。
  • 针排,1块钱很多根,结合杜邦线连接板子和传感器。
  • USB线,特制的,方口的一头接板子,另一头接电脑(供电和调试),板子一般都会送。

软件

  • Arduino IDE 最新版,点我下载
  • 用于MacOS的USB转串口驱动,点我下载

文档

  • DHT11说明书,点我下载
  • Arduino 原理图,点我下载
  • Arduino 板子简介

操作步骤

硬件

程序

double Fahrenheit(double celsius) 
{
        return 1.8 * celsius + 32;
}    //摄氏温度度转化为华氏温度

double Kelvin(double celsius)
{
        return celsius + 273.15;
}     //摄氏温度转化为开氏温度

// 露点(点在此温度时,空气饱和并产生露珠)
// 参考: [url=http://wahiduddin.net/calc/density_algorithms.htm]http://wahiduddin.net/calc/density_algorithms.htm[/url] 
double dewPoint(double celsius, double humidity)
{
        double A0= 373.15/(273.15 + celsius);
        double SUM = -7.90298 * (A0-1);
        SUM += 5.02808 * log10(A0);
        SUM += -1.3816e-7 * (pow(10, (11.344*(1-1/A0)))-1) ;
        SUM += 8.1328e-3 * (pow(10,(-3.49149*(A0-1)))-1) ;
        SUM += log10(1013.246);
        double VP = pow(10, SUM-3) * humidity;
        double T = log(VP/0.61078);   // temp var
        return (241.88 * T) / (17.558-T);
}

// 快速计算露点,速度是5倍dewPoint()
// 参考: [url=http://en.wikipedia.org/wiki/Dew_point]http://en.wikipedia.org/wiki/Dew_point[/url]
double dewPointFast(double celsius, double humidity)
{
        double a = 17.271;
        double b = 237.7;
        double temp = (a * celsius) / (b + celsius) + log(humidity/100);
        double Td = (b * temp) / (a - temp);
        return Td;
}

#include "dht11.h"

dht11 DHT11;

#define DHT11PIN 4

void setup()
{
  Serial.begin(9600);
  Serial.println("DHT11 TEST PROGRAM ");
  Serial.print("LIBRARY VERSION: ");
  Serial.println(DHT11LIB_VERSION);
  Serial.println();
}

void loop()
{
  Serial.println("\n");

  int chk = DHT11.read(DHT11PIN);

  Serial.print("Read sensor: ");
  switch (chk)
  {
    case DHTLIB_OK: 
                Serial.println("OK"); 
                break;
    case DHTLIB_ERROR_CHECKSUM: 
                Serial.println("Checksum error"); 
                break;
    case DHTLIB_ERROR_TIMEOUT: 
                Serial.println("Time out error"); 
                break;
    default: 
                Serial.println("Unknown error"); 
                break;
  }

  Serial.print("Humidity (%): ");
  Serial.println((float)DHT11.humidity, 2);

  Serial.print("Temperature (oC): ");
  Serial.println((float)DHT11.temperature, 2);

  Serial.print("Temperature (oF): ");
  Serial.println(Fahrenheit(DHT11.temperature), 2);

  Serial.print("Temperature (K): ");
  Serial.println(Kelvin(DHT11.temperature), 2);

  Serial.print("Dew Point (oC): ");
  Serial.println(dewPoint(DHT11.temperature, DHT11.humidity));

  Serial.print("Dew PointFast (oC): ");
  Serial.println(dewPointFast(DHT11.temperature, DHT11.humidity));

  delay(2000);
}

编译并上传到板子上,打开串口监视器,可以看到温度和湿度的输出,还是很快的:
这里写图片描述

可以看到温度摄氏 24度,湿度13%(北京还是挺干燥的,赶紧打开了加湿器),自制温度计就这样完成了。中午去买了一个蓝牙模块,接下来想通过蓝牙把温度传给手机。

总结

参考引用

http://www.arduino.cn/thread-1429-1-2.html
http://www.arduino.cc/en/Main/arduinoBoardUno

www.bkjia.comtruehttp://www.bkjia.com/Androidjc/995841.htmlTechArticle基于 Arduino 的温度+湿度传感器,arduino湿度传感器 虽然根本不懂电路,但经过查阅资料,总算是实现了。在这里做一个记录,以免忘记。...

相关文章

    暂无相关文章
相关搜索: 湿度传感器

帮客评论

视觉看点